@echo off
goto start

++++++++++++++++++++++++++++++++++++++++++++++
      Toshiba America Information Systems
      Windows NT 4.0 Utilities/Subsystem
   online distribution installation routine
              03-24-1997 CDC
++++++++++++++++++++++++++++++++++++++++++++++

:start
rem check for presence of a web browser and set environment to appropriate
rem value.  Checks for either MSIE or Netscape and will also extract and
rem display the HTML docs on a Win95 system

if exist "C:\program files\plus!\microsoft internet\iexplore.exe" goto htmlc
if exist "C:\program files\internet explorer\iexplore.exe" goto htmlc
if exist "C:\program files\netscape\navigator\program\netscape.exe" goto htmlc

if exist "D:\program files\plus!\microsoft internet\iexplore.exe" goto htmld
if exist "D:\program files\internet explorer\iexplore.exe" goto htmld
if exist "D:\program files\netscape\navigator\program\netscape.exe" goto htmld

if exist "E:\program files\plus!\microsoft internet\iexplore.exe" goto htmle
if exist "E:\program files\internet explorer\iexplore.exe" goto htmle
if exist "E:\program files\netscape\navigator\program\netscape.exe" goto htmle

goto ascii

:htmlc
set toshie=C:
ren c.lnk 95.lnk
goto htmlcopy

:htmld
set toshie=D:
ren d.lnk 95.lnk
goto htmlcopy

:htmle
set toshie=E:

:htmlcopy
rem make directory for HTML files and start MSIE
md %toshie%\Toshtml >nul
copy .\html\*.* %toshie%\toshtml >nul
copy readme.txt c:\TOSHREAD.NT4 >nul
copy .\html\toshnt40.htm c:\ >nul
if not "%OS%"=="Windows_NT" goto win95
cls
start %toshie%\toshtml\ntinst.htm
goto install


:ascii
copy readme.txt c:\TOSHREAD.NT4 >nul
copy .\html\toshnt40.htm c:\ >nul
cls
echo.
echo.
echo Close Notepad to continue the installation...
notepad readme.txt

:install
cls
echo.
echo.
echo Do you want to install the Windows NT 4.0 Utilities now?
askit
if errorlevel 1 goto cancel
cd disk1
setup
cls
echo.
echo.
echo The Windows NT SCI Drivers are done!
echo The Windows NT APM Subsystem Components are next
pause
cd ..\disk2
setup
cls
echo.
echo.
echo The Windows NT APM Subsystem Components are done!
echo Now all that remains is to finish by installing the
echo Toshiba Windows NT Utilities
pause
cd ..\disk3
setup
if "%toshie%"=="" goto end
start %toshie%\toshtml\index.htm
goto end

:win95
cls
if not exist %toshie%\windows\desktop\*.* goto nodt
copy 95.lnk "%toshie%\windows\desktop\Toshiba NT 4.0 Info.lnk"
echo.
echo.
echo.
echo This software requires Windows NT 4.x
echo Please see the HTML documentation in the %toshie%\Toshtml folder
pause
start %toshie%\toshtml\index.htm
goto end

:nodt
cls
echo.
echo.
echo.
echo This software requires Windows NT 4.x
echo Please see the C:\TOSHREAD.NT4 file for more information
echo.
echo.
pause
goto end


:cancel
cls
echo.
echo.
echo Installation aborted!
echo Please see C:\TOSHREAD.NT4 for installation instructions
echo.
pause

:end
cls
